bank.ado.asp

• Download the Source Workbook (Right-Click, Save Target As...)
• Run this Sample Script

  ---

<%@ LANGUAGE = VBScript %>
<% Option Explicit %>
<%
  '----------------------------------------------------------------------
  ' bank.asp - SpeedGen ASP Sample Script
  ' (c) 2000-2002 Optimized Software Ltd. All Rights Reserved.
  '----------------------------------------------------------------------
  ' This script demonstrates:
  '  - Reading ADO RecordSets
  '  - Positioning of Multiple RecordSets into different spots on the same Sheet. 
  '  - Multiple RecordSources on the same Excel row.
  '  - Sum (Total) of a Field in a RecordSet. This can be applied to any formula.
  '  - Using Variable Field Markers and Live Data (RecordSet) Field Markers on the same Sheet.
  '
  ' Notes:
  '  - Do NOT write any HTML or use Response.Write!
  '  - Server Side (or no) Cursors can cause queries (and stored procedures) to
  '    be executed multiple times! Using a Client Side Cursor will prevent this.
  '----------------------------------------------------------------------
  ' Tip: Code Library at http://www.excelspeedgen.com/code
  '----------------------------------------------------------------------
  Dim dbFile          ' Database File
  Dim oConn           ' ADO Connection object

  Dim Rs1             ' Record Source 1
  Dim Rs2             ' Record Source 2
  Dim Rs3             ' Record Source 3
  Dim Rs4             ' Record Source 4

  Dim XLS             ' SpeedGen Object
  Dim SrcBook         ' Source Workbook

  ' Open Microsoft Access Database
  dbFile = Server.MapPath("sample.mdb")
  Set oConn = Server.CreateObject("ADODB.Connection")
  oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & dbFile

  ' Open the RecordSets
  Set Rs1 = oConn.Execute("BankDeposits") ' SQL Statement (or Table name)
  Set Rs2 = oConn.Execute("BankTransfers") ' SQL Statement (or Table name)
  Set Rs3 = oConn.Execute("BankCharges") ' SQL Statement (or Table name)
  Set Rs4 = oConn.Execute("BankChecks") ' SQL Statement (or Table name)

  ' Create Excel File
  Set XLS = Server.CreateObject("XLSpeedGen.ASP")
  XLS.EstimatedSize = 50000 ' Set Estimated Output File Size (Critical for speed)
  ' Add Variables
  XLS.AddVariable "ReportMonth", Now ' for >>$ReportMonth Field Marker
  XLS.AddVariable "Name", "Mark Matthews" ' for >>$Name Field Marker
  XLS.AddVariable "AccountNum", 105930 ' for >>$AccountNum Field Marker

  ' Add RecordSources
  XLS.AddRS_ADO Rs1, 20 ' RecordSource 1 (read 20 rows at a time)
  XLS.AddRS_ADO Rs2, 20 ' RecordSource 2 (read 20 rows at a time)
  XLS.AddRS_ADO Rs3, 20 ' RecordSource 3 (read 20 rows at a time)
  XLS.AddRS_ADO Rs4, 20 ' RecordSource 4 (read 20 rows at a time)

  SrcBook = Server.MapPath("bank.xls") ' Location of Source Workbook
  XLS.Generate SrcBook, "", True ' Generate SpreadSheet and Stream to Client, Open in Place

  Set XLS = Nothing ' Destroy object when done

  ' Cleanup Code
  oConn.close ' Close Connection and all Recordsets
  Set oConn = Nothing
%>